      SUBROUTINE PDPOTF2( UPLO, N, A, IA, JA, DESCA, INFO)
* 
*  -- ScaLAPACK routine (version 1.2) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 10, 1996
*
C  -- Modified by Peter Strazdins, DCS, Australian National University 09/96
C     to enable algorithmic blocking by a width JA. Modifications include:
C               1. relaxing error checking
C               2. adding separate code to handle JA > NB.
C		3. changing error handling for non +ve definiteness.
C		   to avoid extra b/c of INFO, computation will continue
C		   as for pdgetrf()/pdgetf2()  (avoiding division by 0.0 etc)   
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( * )
*     ..
*
*  Purpose
*  =======
*
*  PDPOTF2 computes the Cholesky factorization of a real symmetric
*  positive definite distributed matrix sub( A )=A(IA:IA+N-1,JA:JA+N-1).
*
*  The factorization has the form
*
*            sub( A ) = U' * U ,  if UPLO = 'U', or
*
*            sub( A ) = L  * L',  if UPLO = 'L',
*
*  where U is an upper triangular matrix and L is lower triangular.
*
*  Notes
*  =====
*
*  A description vector is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This vector stores the information required to
*  establish the mapping between a matrix entry and its corresponding
*  process and memory location.
*
*  In the following comments, the character _ should be read as
*  "of the distributed matrix".  Let A be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DT_A   (global) DESCA( DT_ )   The descriptor type.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the distributed
*                                 matrix A.
*  N_A    (global) DESCA( N_ )    The number of columns in the distri-
*                                 buted matrix A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of A.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of A.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the matrix A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of A is distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array storing the local blocks of the
*                                 distributed matrix A.
*                                 LLD_A >= MAX(1,LOCp(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCp( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCq( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCp() and LOCq() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCp( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCq( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*
*  This routine requires N <= NB_A-MOD(JA-1, NB_A) and square block
*  decomposition ( MB_A = NB_A ).
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          = 'U':  Upper triangle of sub( A ) is stored;
*          = 'L':  Lower triangle of sub( A ) is stored.
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_A, LOCq(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          N-by-N symmetric distributed matrix sub( A ) to be factored.
*          If UPLO = 'U', the leading N-by-N upper triangular part of
*          sub( A ) contains the upper triangular part of the matrix,
*          and its strictly lower triangular part is not referenced.
*          If UPLO = 'L', the leading N-by-N lower triangular part of
*          sub( A ) contains the lower triangular part of the distribu-
*          ted matrix, and its strictly upper triangular part is not
*          referenced.  On exit, if UPLO = 'U', the upper triangular
*          part of the distributed matrix contains the Cholesky factor
*          U, if UPLO = 'L', the lower triangular part of the distribu-
*          ted matrix contains the Cholesky factor L.
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*          > 0:  If INFO = K, the leading minor of order K,
*                A(IA:IA+K-1,JA:JA+K-1) is not positive definite, and
*                the factorization could not be completed.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DT_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      PARAMETER          ( BLOCK_CYCLIC_2D = 1, DLEN_ = 9, DT_ = 1,
     $                     CTXT_ = 2, M_ = 3, N_ = 4, MB_ = 5, NB_ = 6,
     $                     RSRC_ = 7, CSRC_ = 8, LLD_ = 9 )
      DOUBLE PRECISION   ONE, ZERO
      PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IACOL, IAROW, ICOFF, ICTXT, IIA,
     $                   IROFF, I, J, JJA, MYCOL, MYROW,
     $                   NPCOL, NPROW
      DOUBLE PRECISION   AJJ
*     ..
*     .. External Subroutines ..
      EXTERNAL           BLACS_ABORT, BLACS_GRIDINFO, CHK1MAT, DGEMV,
     $                   DSCAL, IGEBR2D, IGEBS2D, INFOG2L, PTOPGET,
     $                   PXERBLA, PDSCAL, PDSET, PDGESD2D, PDGER2D
     $                   PDELSET, PDELGET
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          MAX, MOD, SQRT
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2P, NUMROC
      DOUBLE PRECISION   DDOT
      EXTERNAL           INDXG2P, LSAME, NUMROC, DDOT
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ICTXT = DESCA( CTXT_ )
      CALL BLACS_GRIDINFO( ICTXT, NPROW, NPCOL, MYROW, MYCOL )
*
*     Test the input parameters.
*
      INFO = 0
      IF( NPROW.EQ.-1 ) THEN
         INFO = -(600+CTXT_)
      ELSE
         CALL CHK1MAT( N, 2, N, 2, IA, JA, DESCA, 6, INFO )
         IF( INFO.EQ.0 ) THEN
            UPPER = LSAME( UPLO, 'U' )
            IROFF = MOD( IA-1, DESCA( MB_ ) )
            ICOFF = MOD( JA-1, DESCA( NB_ ) )
            IF ( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
               INFO = -1
c            ELSE IF( N+ICOFF.GT.DESCA( NB_ ) ) THEN
c               INFO = -2
            ELSE IF( IROFF.NE.0 ) THEN
               INFO = -4
            ELSE IF( ICOFF.NE.0 ) THEN
               INFO = -5
            ELSE IF( DESCA( MB_ ).NE.DESCA( NB_ ) ) THEN
               INFO = -(600+NB_)
            END IF
         END IF
      END IF
*
      IF( INFO.NE.0 ) THEN
         CALL PXERBLA( ICTXT, 'PDPOTF2', -INFO )
         CALL BLACS_ABORT( ICTXT, 1 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( N.EQ.0 )
     $   RETURN
*
*     Compute local information
*
      CALL INFOG2L( IA, JA, DESCA, NPROW, NPCOL, MYROW, MYCOL, IIA, JJA,
     $              IAROW, IACOL )
      CALL PTOPGET( ICTXT, 'Broadcast', 'Rowwise', ROWBTOP )
      CALL PTOPGET( ICTXT, 'Broadcast', 'Columnwise', COLBTOP )
*
      IF ( UPPER ) THEN
*
          DO 10 J =  JA, JA+N-1
		I = J+IA-JA
 		IF( MYROW.EQ.IAROW ) THEN
		  CALL PDELGET('R',ROWBTOP,AJJ,A,I,J,DESCA)      
		  IF (AJJ .GT. ZERO) THEN
		    AJJ = SQRT(AJJ)	
		    CALL PDSCAL( JA+N-J-1, ONE / AJJ, A, I, J+1, 
     $                           DESCA, DESCA( M_ ) )
		  ELSE 
		    IF (INFO .EQ. 0) INFO = J - JA + 1	
C		    avoid division by 0 in subsequent PDTRSM() 
		    IF (AJJ .EQ. 0.0) AJJ = ONE
		  ENDIF
		  CALL PDELSET( A, I, J, DESCA, AJJ )
   		ENDIF
       	        CALL PDSYR(UPLO, JA+N-J-1, -ONE, A, I, J+1, DESCA, 
     $                     DESCA( M_ ), A, I+1, J+1, DESCA)
		IROFF = IROFF + 1
		IF (IROFF .EQ. DESCA(NB_)) THEN
		  IROFF = 0
		  IAROW = IAROW + 1
		  IF (IAROW .EQ. NPROW) IAROW = 0
		END IF
   10     CONTINUE
      ELSE
          DO 30 J = JA, JA+N-1
		I = J+IA-JA
 		IF( MYCOL.EQ.IACOL ) THEN
		  CALL PDELGET('C',COLBTOP, AJJ, A, I, J, DESCA)
		  IF (AJJ .GT. ZERO) THEN
  		    AJJ = SQRT(AJJ)
  		    CALL PDSCAL( JA+N-J-1, ONE / AJJ, A, I+1, J, 
     $		                 DESCA, 1 )
		  ELSE 
		    IF (INFO .EQ. 0) INFO = J - JA + 1	
C		    avoid division by 0 in subsequent PDTRSM() 
		    IF (AJJ .EQ. 0.0) AJJ = ONE
		  ENDIF
  		  CALL PDELSET( A, I, J, DESCA, AJJ )
 		ENDIF
		CALL PDSYR(UPLO, JA+N-J-1, -ONE, A, I+1, J, DESCA, 1,
     $			   A, I+1, J+1, DESCA)
		ICOFF = ICOFF + 1
		IF (ICOFF .EQ. DESCA(MB_)) THEN
		  ICOFF = 0
		  IACOL = IACOL + 1
		  IF (IACOL .EQ. NPCOL) IACOL = 0
		END IF
*
   30     CONTINUE
*
      END IF
*     
*	
      RETURN
*
*     End of PDPOTF2
*
      END
